/declare/ integer n_disk = 2, n_term;    & global variables
   real visits(n_disk);                  & dimension n_disk must be init.
   queue real serv_t;                    & param for every queue  queue.serv_t
   queue cpu,terms,disk(n_disk);         & station identifiers
&
/station/ name=cpu;
   service = exp(serv_t);                & in a station, serv_t stands
                                         & for name.serv_t
   transit = disk(1 step 1 until n_disk),
        visits (1 step 1 until n_disk), terms, 1;
                       & where list, rel. prob. list, where list, prob list ..;
&
/station/ name = disk(1 step 1 until n_disk);
   transit = cpu;
   service = exp(serv_t);
&
/station/ name = terms;
   init = n_term;                      & params here do not have to be init
   type = infinite;             & standard types infinite, multiple, etc.
                                & default type is single server
   service = exp(serv_t);
   transit = cpu,1;
&
/exec/ begin
   &init variables 
   visits(1):= 9;
   visits(2):= 4;
   disk(1).serv_t:= 0.015;
   disk(2).serv_t:= 0.030;
   cpu.serv_t := 0.15;
   terms.serv_t:= 10;
   & loop for multiple solutions
   for n_term := 3,6,12,18 do
      begin
      & init variables for each if necessary (none here)
      print("no of terminals = ", n_term);
      solve;       & qnap decides what solver to use (MVA by preference)
      output;      & default output variables and format
      end;
   end;
/terminal/